Azure AI Search'te , $orderbyve $select için $filterOData diline genel bakış

Bu makalede, Azure AI Search'te $filtersayısal ve $select dize (seçici olmayan) alanları üzerinden anahtar sözcük araması için , $order-byve ifadelerinde kullanılan OData ifade diline genel bir bakış sağlanır.

Dil, en temel öğelerden başlayarak "aşağıdan yukarıya" sunulur. Sorgu isteğinde oluşturabileceğiniz OData ifadeleri basitten yüksek karmaşıklığa kadar değişir, ancak bunların tümü ortak öğeleri paylaşır. Paylaşılan öğeler şunlardır:

• Dizininizin belirli alanlarına başvuran alan yolları.
• Sabitler, belirli bir veri türünün değişmez değerleridir.

Bu yaygın kavramları anladıktan sonra, her ifade için en üst düzey söz dizimiyle devam edebilirsiniz:

• $filter ifadeleri sorgu ayrıştırma, aramayı belirli alanlarla sınırlama veya dizin taramaları sırasında kullanılan eşleşme ölçütleri ekleme sırasında değerlendirilir.
• $orderby ifadeler, döndürülen belgeleri sıralamak için bir sonuç kümesi üzerinde işlem sonrası adım olarak uygulanır.
• $select ifadeleri, sonuç kümesine hangi belge alanlarının dahil olduğunu belirler.

Bu ifadelerin söz dizimi, arama parametresinde kullanılan basit veya tam sorgu söz diziminden farklıdır, ancak başvuru alanları için söz diziminde bazı çakışmalar vardır.

Python veya C# gibi diğer dillerdeki örnekler için azure-search-vector-samples deposundaki örneklere bakın.

Alan yolları

Aşağıdaki EBNF (Genişletilmiş Backus-Naur Formu), alan yollarının dil bilgisini tanımlar.

field_path ::= identifier('/'identifier)*

identifier ::= [a-zA-Z_][a-zA-Z_0-9]*

Etkileşimli söz dizimi diyagramı da kullanılabilir:

Alan yolu, eğik çizgilerle ayrılmış bir veya daha fazla tanımlayıcıdan oluşur. Her tanımlayıcı, ASCII harfi veya alt çizgiyle başlaması gereken ve yalnızca ASCII harfleri, basamakları veya alt çizgilerini içeren bir karakter dizisidir. Harfler büyük veya küçük harf olabilir.

Tanımlayıcı, bir alanın adına veya filtredeki bir koleksiyon ifadesi (any veya all) bağlamındaki bir aralık değişkenine başvurabilir. Aralık değişkeni, koleksiyonun geçerli öğesini temsil eden bir döngü değişkeni gibidir. Karmaşık koleksiyonlar için bu değişken bir nesneyi temsil eder ve bu nedenle değişkenin alt alanlarına başvurmak için alan yollarını kullanabilirsiniz. Bu, birçok programlama dilinde nokta gösterimine benzer.

Alan yolu örnekleri aşağıdaki tabloda gösterilmiştir:

Alan yolunun anlamı bağlama bağlı olarak değişir. Filtrelerde, alan yolu geçerli belgedeki bir alanın tek bir örneğinin değerine başvurur. $orderby, $select gibi diğer bağlamlarda veya tam Lucene söz dizimindeki alanlı aramada, alan yolu alanın kendisine başvurur. Bu farkın, filtrelerde alan yollarını nasıl kullandığınıza ilişkin bazı sonuçları vardır.

alan yolunu Address/Citygöz önünde bulundurun. Filtrede bu, geçerli belge için "San Francisco" gibi tek bir şehir anlamına gelir. Buna karşılık, Rooms/Type birçok odanın alt alanını ifade eder Type (birinci oda için "standart", ikinci oda için "deluxe" vb.). Rooms/Type alt alanının Typetek bir örneğine başvurmadığından, doğrudan bir filtrede kullanılamaz. Bunun yerine, oda türüne göre filtrelemek için aşağıdaki gibi bir aralık değişkenine sahip bir lambda ifadesi kullanırsınız:

Rooms/any(room: room/Type eq 'deluxe')

Bu örnekte, aralık değişkeni room alan yolunda görüntülenir room/Type . Bu şekilde, room/Type geçerli belgedeki geçerli odanın türüne başvurur. Bu alt alanı tek bir örneğidir Type , bu nedenle doğrudan filtrede kullanılabilir.

Alan yollarını kullanma

Alan yolları, Azure AI Search REST API'lerinin birçok parametresinde kullanılır. Aşağıdaki tabloda, kullanabilecekleri tüm yerler ve kullanımlarıyla ilgili kısıtlamalar listelenecektir:

Sabitler

OData'daki sabitler, belirli bir Varlık Veri Modeli (EDM) türünün değişmez değerleridir. Azure AI Search'te desteklenen türlerin listesi için bkz . Desteklenen veri türleri . Koleksiyon türlerinin sabitleri desteklenmez.

Aşağıdaki tabloda, OData ifadelerini destekleyen her bir seçici olmayan veri türü için sabit örnekleri gösterilmektedir:

Dize sabitlerindeki özel karakterlerden kaçış

OData'daki dize sabitleri tek tırnak işaretleri ile sınırlandırılır. Tek tırnak işareti içerebilen bir dize sabiti içeren bir sorgu oluşturmanız gerekiyorsa, katıştırılmış tırnakları ikiye katlayarak kaçabilirsiniz.

Örneğin, "Alice'in arabası" gibi biçimlendirilmemiş kesme işaretine sahip bir tümcecik, OData'da dize sabiti 'Alice''s car'olarak temsil edilir.

Sabitler söz dizimi

Aşağıdaki EBNF (Genişletilmiş Backus-Naur Formu), yukarıdaki tabloda gösterilen sabitlerin çoğu için dil bilgisini tanımlar. Coğrafi uzamsal türler için dil bilgisi, Azure AI Search'teki OData coğrafi uzamsal işlevlerinde bulunabilir.

constant ::=
    string_literal
    | date_time_offset_literal
    | integer_literal
    | float_literal
    | boolean_literal
    | 'null'

string_literal ::= "'"([^'] | "''")*"'"

date_time_offset_literal ::= date_part'T'time_part time_zone

date_part ::= year'-'month'-'day

time_part ::= hour':'minute(':'second('.'fractional_seconds)?)?

zero_to_fifty_nine ::= [0-5]digit

digit ::= [0-9]

year ::= digit digit digit digit

month ::= '0'[1-9] | '1'[0-2]

day ::= '0'[1-9] | [1-2]digit | '3'[0-1]

hour ::= [0-1]digit | '2'[0-3]

minute ::= zero_to_fifty_nine

second ::= zero_to_fifty_nine

fractional_seconds ::= integer_literal

time_zone ::= 'Z' | sign hour':'minute

sign ::= '+' | '-'

/* In practice integer literals are limited in length to the precision of
the corresponding EDM data type. */
integer_literal ::= digit+

float_literal ::=
    sign? whole_part fractional_part? exponent?
    | 'NaN'
    | '-INF'
    | 'INF'

whole_part ::= integer_literal

fractional_part ::= '.'integer_literal

exponent ::= 'e' sign? integer_literal

boolean_literal ::= 'true' | 'false'

Etkileşimli söz dizimi diyagramı da kullanılabilir:

Alan yollarından ve sabitlerden ifade oluşturma

Alan yolları ve sabitleri, OData ifadesinin en temel parçasıdır, ancak bunlar zaten tam ifadelerdir. Aslında Azure AI Search'teki $select parametresi, alan yollarının virgülle ayrılmış bir listesinden başka bir şey değildir ve $orderby $select kadar karmaşık değildir. Dizininizde türünde Edm.Boolean bir alan varsa, o alanın yolundan başka bir şey olmayan bir filtre bile yazabilirsiniz. sabitleri true ve false benzer şekilde geçerli filtrelerdir.

Ancak, birden çok alana ve sabite başvuran karmaşık ifadelerin olması daha yaygındır. Bu ifadeler, parametresine bağlı olarak farklı şekillerde oluşturulur.

Aşağıdaki EBNF (Genişletilmiş Backus-Naur Formu), $filter, $orderby ve $select parametreleri için dil bilgisini tanımlar. Bunlar, alan yollarına ve sabitlerine başvuran daha basit ifadelerden oluşturulur:

filter_expression ::= boolean_expression

order_by_expression ::= order_by_clause(',' order_by_clause)*

select_expression ::= '*' | field_path(',' field_path)*

Etkileşimli söz dizimi diyagramı da kullanılabilir:

Sonraki adımlar

$orderby ve $select parametreleri, daha basit ifadelerin virgülle ayrılmış listeleridir. $filter parametresi, daha basit alt ifadelerden oluşan bir Boole ifadesidir. Bu alt ifadeler, , orve notgibiand mantıksal işleçler, vb. gibi ltgteqkarşılaştırma işleçleri ve ve gibi any allkoleksiyon işleçleri kullanılarak birleştirilir.

$filter, $orderby ve $select parametreleri aşağıdaki makalelerde daha ayrıntılı olarak incelenir:

• Azure AI Search'te OData $filter söz dizimi
• Azure AI Search'te OData $orderby söz dizimi
• Azure AI Search'te OData $select söz dizimi