Visual Basic 2008 重大更改

可以为 null 的类型

T 扩大为 T?在 Visual Studio 2008 中是预定义的转换。

在 Visual Studio 2005 中，可以创建用户定义的转换，以使 T 可以扩大为 Nullable(Of T)。为了更好地支持可以为 null 的类型，在 Visual Studio 2008 中预定义了此转换。

由于重载决策会同时考虑预定义转换和用户定义的转换，因此当两者同时存在时可能会出现多义性。因此，如果代码包含从 T 到 T? 的用户定义的扩大转换，该代码在 Visual Studio 2008 中可能是不明确的。

例如，在下面的代码中，对 c3.Sub1 的调用可在 Visual Studio 2005 中正常运行，但在 Visual Studio 2008 中会导致编译器错误。

Module Module1

    Sub Main()
        Dim c3 As New Class3
        Dim sh As Short = 2
        ' The following statement compiles in Visual Studio 2005,
        ' but causes an error in Visual Studio 2008.
        'c3.Sub1(sh)
    End Sub

End Module

Class Class1
    Public Shared Widening Operator CType(ByVal s As  _
                                          Nullable(Of Short)) As Class1
        Return New Class1()
    End Operator
End Class

Class Class2
    Public Shared Widening Operator CType(ByVal n As Integer) As Class2
        Return New Class2()
    End Operator
End Class

Class Class3
    Sub Sub1(ByVal c As Class1)
    End Sub

    Sub Sub1(ByVal c As Class2)
    End Sub
End Class

若要解决此问题，可以移除用户定义的转换，也可以显式强制转换为 Class1 或 Class2：

c3.Sub1(CType(sh, Class1))

重载决策

具有泛型和 ParamArray 参数的重载决策在 Visual Studio 2008 中会生成不同的结果。

重载决策的目标是尝试选择最合适的候选方法，该候选方法的形参应最为匹配传递给该方法的实参的类型。在本节的示例中，Sub1 在继承层次结构之中进行重载，并使用类型为 Integer 和 Short 的参数进行调用。

Visual Studio 2005 和 Visual Studio 2008 中的重载决策规则都指定直接匹配优于需要 ParamArray 参数的匹配。但是在使用 Visual Studio 2005 重载决策规则时，类型推理无法用于派生类 Class2 中的重载候选，因为 Y 不能同时为 Integer 和 Short，因而需要精确匹配。如果实参 sh 和 n 具有相同的类型，则 Class2 中的 Sub1 比 Class1 中的重载候选更为可取，因为后者有一个 ParamArray 形参。但是，由于这两个实参的类型不同，因此会改为选择 Class1 中的基类重载。T 会推断为 Integer，而 Short 扩大为 ParamArrayp。

Visual Studio 2008 使用一种新的算法，该算法选择的重载与 Visual Studio 2005 中选择的重载相同（除了在此特定情况下）。在 Visual Studio 2008 中，该算法在此示例中确定 Integer 为主导类型，因为 Short 扩大为 Integer。派生类中的类型参数 Y 推理为 Integer，而 Short 扩大为 Integer。因此，将调用派生类中的 Sub1。

Module Module1

    Sub Main()
        Dim c2 As New Class2
        Dim n As Integer
        Dim sh As Short
        c2.Sub1(n, sh)
    End Sub

    Class Class1
        Sub Sub1(Of T)(ByVal arg1 As T, ByVal ParamArray p() As Integer)
            Console.WriteLine("Visual Studio 2005 calls Sub1 " & _
                              "in the *base* class.")
        End Sub
    End Class

    Class Class2 : Inherits Class1
        Overloads Sub Sub1(Of Y)(ByVal arg1 As Y, ByVal arg2 As Y)
            Console.WriteLine("Visual Studio 2008 calls Sub1 " & _
                              "in the *derived* class.")
        End Sub
    End Class

End Module

通过在调用 Sub1 之前将变量 c2 强制转换为类型 C1ass1，或是通过将参数 sh 作为数组进行传递，可以强制执行 Visual Studio 2005 行为。

' You can cast variable c2 to Class1 in order to force Visual
' Studio 2005 behavior.
CType(c2, Class1).Sub1(n, sh)
' Alternatively, you can pass sh as an array.
c2.Sub1(n, New Integer() {sh})

2008 年 7 月

新增主题。

信息补充。