使用 TOP 來限制插入的資料列

您可以使用 TOP 關鍵字來限制插入的資料列數。

下例會建立 NewEmployee 資料表，並在其中插入 Employee 資料表的前 10 位員工的地址資料。然後執行 SELECT 陳述式以驗證 NewEmployee 資料表的內容。

USE AdventureWorks;
GO
IF OBJECT_ID (N'HumanResources.NewEmployee', N'U') IS NOT NULL
    DROP TABLE HumanResources.NewEmployee;
GO
CREATE TABLE HumanResources.NewEmployee
(
    EmployeeID int NOT NULL,
    LastName nvarchar(50) NOT NULL,
    FirstName nvarchar(50) NOT NULL,
    Phone Phone NULL,
    AddressLine1 nvarchar(60) NOT NULL,
    City nvarchar(30) NOT NULL,
    State nchar(3) NOT NULL, 
    PostalCode nvarchar(15) NOT NULL,
    CurrentFlag Flag
);
GO
INSERT TOP (10) INTO HumanResources.NewEmployee 
    SELECT
       e.EmployeeID, c.LastName, c.FirstName, c.Phone,
       a.AddressLine1, a.City, sp.StateProvinceCode, 
       a.PostalCode, e.CurrentFlag
    FROM HumanResources.Employee e
        INNER JOIN HumanResources.EmployeeAddress AS ea
        ON e.EmployeeID = ea.EmployeeID
        INNER JOIN Person.Address AS a
        ON ea.AddressID = a.AddressID
        INNER JOIN Person.StateProvince AS sp
        ON a.StateProvinceID = sp.StateProvinceID
        INNER JOIN Person.Contact as c
        ON e.ContactID = c.ContactID;
GO
SELECT  EmployeeID, LastName, FirstName, Phone,
        AddressLine1, City, State, PostalCode, CurrentFlag
FROM HumanResources.NewEmployee;
GO

請參閱

概念

使用 TOP 與 PERCENT 限制結果集
使用 INSERT 和 Values 插入資料列
使用 INSERT 和 SELECT 子查詢插入資料列
使用 SELECT INTO 插入資料列
使用 INSERT 與 SELECT 加入資料列

其他資源

INSERT (Transact-SQL)
TOP (Transact-SQL)
SELECT (Transact-SQL)

說明及資訊

取得 SQL Server 2005 協助