sp_posttracertoken (Transact-SQL)
適用於:SQL Server
此程式會將追蹤令牌張貼到發行者端的事務歷史記錄中,並開始追蹤延遲統計數據的程式。 當追蹤令牌寫入事務歷史記錄、記錄讀取器代理程式所挑選,以及 散發代理程式 套用時,就會記錄資訊。 這個預存程式會在發行集資料庫的發行者端執行。 如需相關資訊,請參閱 針對異動複寫測量延遲及驗證連接。
語法
sp_posttracertoken [ @publication = ] 'publication'
[ , [ @tracer_token_id = ] tracer_token_id OUTPUT
[ , [ @publisher = ] 'publisher'
引數
[ @publication = ] 'publication'
這是要測量延遲的發行集名稱。 publication 是 sysname,沒有預設值。
[ @tracer_token_id = ] _tracer_token_id OUTPUT
這是插入的追蹤令牌識別碼。 tracer_token_id的預設值為 NULL,且為 OUTPUT 參數。 這個值可以用來執行sp_helptracertokenhistory (Transact-SQL) 或 sp_deletetracertokenhistory (Transact-SQL),而不需要先執行 sp_helptracertokens (Transact-SQL)。
[ @publisher = ] 'publisher'
指定非Microsoft SQL Server 發行者。 publisher 是 sysname,預設值為 NULL,不應該為 SQL Server 發行者指定。
傳回碼值
0 (成功) 或 1 (失敗)
備註
sp_posttracertoken用於事務複製。
範例
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran';
USE [AdventureWorks2022]
-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken
@publication = @publication,
@tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' +
CONVERT(varchar,@tokenID) + '''.'
GO
-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO
-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran';
CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)
-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens
-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory
@publication = @publication,
@tracer_id = @tokenID;
GO
權限
只有系統管理員固定伺服器角色或db_owner固定資料庫角色的成員才能執行sp_posttracertoken。