IteratorStateMachineAttribute Třída

Definice

public ref class IteratorStateMachineAttribute sealed : System::Runtime::CompilerServices::StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
[System.Serializable]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
[<System.Serializable>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

Public NotInheritable Class IteratorStateMachineAttribute
Inherits StateMachineAttribute

Dědičnost

Object

Attribute

StateMachineAttribute

IteratorStateMachineAttribute

Atributy

AttributeUsageAttribute SerializableAttribute

Příklady

Následující příklad ukazuje, jak určit, zda je metoda iterátoru. V příkladu IsIteratorMethod provede následující kroky:

• MethodInfo Získá objekt pro název metody pomocí Type.GetMethod.

• Type Získá objekt pro atribut pomocí GetType Operátor.

• Získá objekt atributu pro metodu a typ atributu pomocí MethodInfo.GetCustomAttribute. Pokud GetCustomAttribute vrátí Nothing (Visual Basic), metoda neobsahuje atribut .

Imports System.Collections.Generic
Imports System.Reflection
Imports System.Threading.Tasks
Imports System.Runtime.CompilerServices


Module Module1

    ' This class is used by the code below to discover method attributes.
    Public Class TheClass
        Public Async Function AsyncMethod() As Task(Of Integer)
            Await Task.Delay(5)
            Return 1
        End Function

        Public Iterator Function IteratorMethod() As IEnumerable(Of Integer)
            Yield 1
            Yield 2
        End Function

        Public Function RegularMethod() As Integer
            Return 0
        End Function
    End Class


    Private Function IsAsyncMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(AsyncStateMachineAttribute)

        Dim attrib = CType(method.GetCustomAttribute(attType), AsyncStateMachineAttribute)
        ' The above variable contains the StateMachineType property.

        Return (attrib IsNot Nothing)
    End Function

    Private Function IsIteratorMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(IteratorStateMachineAttribute)

        ' Obtain the custom attribute for the method.
        ' The value returned contains the StateMachineType property.
        ' Nothing is returned if the attribute isn't present for the method.
        Dim attrib = CType(method.GetCustomAttribute(attType), IteratorStateMachineAttribute)

        Return (attrib IsNot Nothing)
    End Function

    Private Sub ShowResult(classType As Type, methodName As String)
        Console.Write((methodName & ": ").PadRight(16))

        If IsAsyncMethod(classType, methodName) Then
            Console.WriteLine("Async method")
        ElseIf IsIteratorMethod(classType, methodName) Then
            Console.WriteLine("Iterator method")
        Else
            Console.WriteLine("Regular method")
        End If

        ' Note: The IteratorStateMachineAttribute applies to Visual Basic methods
        ' but not C# methods.
    End Sub

    Sub Main()
        ShowResult(GetType(TheClass), "AsyncMethod")
        ShowResult(GetType(TheClass), "IteratorMethod")
        ShowResult(GetType(TheClass), "RegularMethod")

        Console.ReadKey()
    End Sub

    '   AsyncMethod:    Async method
    '   IteratorMethod: Iterator method
    '   RegularMethod:  Regular method

End Module

Poznámky

Atribut byste neměli IteratorStateMachine používat na metody v kódu. U metod v jazyce Visual Basic, které mají modifikátor Iterator , použije IteratorStateMachine kompilátor atribut v il, který vygeneruje.

Když metoda (MethodName) v jazyce Visual Basic má Iterator modifikátor, kompilátor vygeneruje IL, který obsahuje strukturu stavového počítače. Tato struktura obsahuje kód v metodě. Tento il také obsahuje metodu se zástupným inzerováním (MethodName), která volá stavový počítač. Kompilátor přidá IteratorStateMachine atribut do metody stub, aby nástroje mohly identifikovat odpovídající stavový počítač. Podrobnosti o vygenerovaném IL se můžou v budoucích verzích kompilátorů změnit.

Metoda iterátoru provádí vlastní iteraci nad kolekcí pomocí Yield příkazu (Visual Basic) k vrácení každého prvku po jednom. Další informace najdete v tématu Iterátory.

Konstruktory

Vlastnosti

Metody

Explicitní implementace rozhraní

Platí pro

Viz také

• AsyncStateMachineAttribute
• StateMachineType