IteratorStateMachineAttribute Clase

Definición

public ref class IteratorStateMachineAttribute sealed : System::Runtime::CompilerServices::StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
[System.Serializable]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
[<System.Serializable>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

Public NotInheritable Class IteratorStateMachineAttribute
Inherits StateMachineAttribute

Herencia

Object

Attribute

StateMachineAttribute

IteratorStateMachineAttribute

Atributos

AttributeUsageAttribute SerializableAttribute

Ejemplos

En el ejemplo siguiente se muestra cómo determinar si un método es un método de iterador. En el ejemplo, IsIteratorMethod realiza los pasos siguientes:

• Obtiene un MethodInfo objeto para el nombre del método mediante Type.GetMethod.

• Obtiene un Type objeto para el atributo mediante el operador GetType.

• Obtiene un objeto de atributo para el método y el tipo de atributo mediante MethodInfo.GetCustomAttribute. Si GetCustomAttribute devuelve Nothing (Visual Basic), el método no contiene el atributo .

Imports System.Collections.Generic
Imports System.Reflection
Imports System.Threading.Tasks
Imports System.Runtime.CompilerServices


Module Module1

    ' This class is used by the code below to discover method attributes.
    Public Class TheClass
        Public Async Function AsyncMethod() As Task(Of Integer)
            Await Task.Delay(5)
            Return 1
        End Function

        Public Iterator Function IteratorMethod() As IEnumerable(Of Integer)
            Yield 1
            Yield 2
        End Function

        Public Function RegularMethod() As Integer
            Return 0
        End Function
    End Class


    Private Function IsAsyncMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(AsyncStateMachineAttribute)

        Dim attrib = CType(method.GetCustomAttribute(attType), AsyncStateMachineAttribute)
        ' The above variable contains the StateMachineType property.

        Return (attrib IsNot Nothing)
    End Function

    Private Function IsIteratorMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(IteratorStateMachineAttribute)

        ' Obtain the custom attribute for the method.
        ' The value returned contains the StateMachineType property.
        ' Nothing is returned if the attribute isn't present for the method.
        Dim attrib = CType(method.GetCustomAttribute(attType), IteratorStateMachineAttribute)

        Return (attrib IsNot Nothing)
    End Function

    Private Sub ShowResult(classType As Type, methodName As String)
        Console.Write((methodName & ": ").PadRight(16))

        If IsAsyncMethod(classType, methodName) Then
            Console.WriteLine("Async method")
        ElseIf IsIteratorMethod(classType, methodName) Then
            Console.WriteLine("Iterator method")
        Else
            Console.WriteLine("Regular method")
        End If

        ' Note: The IteratorStateMachineAttribute applies to Visual Basic methods
        ' but not C# methods.
    End Sub

    Sub Main()
        ShowResult(GetType(TheClass), "AsyncMethod")
        ShowResult(GetType(TheClass), "IteratorMethod")
        ShowResult(GetType(TheClass), "RegularMethod")

        Console.ReadKey()
    End Sub

    '   AsyncMethod:    Async method
    '   IteratorMethod: Iterator method
    '   RegularMethod:  Regular method

End Module

Comentarios

No debe aplicar el IteratorStateMachine atributo a los métodos del código. En el caso de los métodos de Visual Basic que tienen el modificador Iterator , el compilador aplicará el IteratorStateMachine atributo en el IL que emite.

Cuando un método (MethodName) de Visual Basic tiene el Iterator modificador , el compilador emite IL que incluye una estructura de máquina de estado. Esa estructura contiene el código en el método . Ese IL también contiene un método de código auxiliar (MethodName) que llama a en la máquina de estado. El compilador agrega el IteratorStateMachine atributo al método de código auxiliar para que las herramientas puedan identificar la máquina de estado correspondiente. Los detalles del IL emitido pueden cambiar en futuras versiones de los compiladores.

Un método de iterador realiza una iteración personalizada sobre una colección mediante la Yield instrucción (Visual Basic) para devolver cada elemento de uno en uno. Para obtener más información, consulta Iteradores.

Constructores

Propiedades

Métodos

Implementaciones de interfaz explícitas

Se aplica a

Consulte también

• AsyncStateMachineAttribute
• StateMachineType