sp_posttracertoken (Transact-SQL)

  • Artículo

Se aplica a: SQL Server

Este procedimiento envía un testigo de seguimiento al registro de transacciones del publicador y empieza el proceso de seguimiento de las estadísticas de latencia.

La información se registra:

  • cuando el token del seguimiento se escribe en el registro de transacciones;
  • cuando el Agente de registro del log lo recoge; y
  • cuando el Agente de distribución lo aplica.

Este procedimiento almacenado se ejecuta en el publicador de la base de datos de publicación. Para más información, consulte Medir la latencia y validar las conexiones de la replicación transaccional.

Convenciones de sintaxis de Transact-SQL

Sintaxis

sp_posttracertoken
    [ @publication = ] N'publication'
    [ , [ @tracer_token_id = ] tracer_token_id OUTPUT ]
    [ , [ @publisher = ] N'publisher' ]
[ ; ]

Argumentos

[ @publication = ] N'publication'

Nombre de la publicación para la que se mide la latencia. @publication es sysname, sin ningún valor predeterminado.

[ @tracer_token_id = ] tracer_token_id OUTPUT

Identificador del token de seguimiento insertado. @tracer_token_id es un parámetro OUTPUT de tipo int. Este valor se puede usar para ejecutar sp_helptracertokenhistory o sp_deletetracertokenhistory sin ejecutar primero sp_helptracertokens.

[ @publisher = ] N'publisher'

Especifica un publicador que no es de SQL Server. @publisher es sysname, con un valor predeterminado de NULL. Este parámetro no se debe especificar para un publicador de SQL Server.

Valores de código de retorno

0 (correcto) o 1 (erróneo).

Comentarios

sp_posttracertoken se usa en la replicación transaccional.

Ejemplos

DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

USE [AdventureWorks2022]

-- Insert a new tracer token in the publication database.
EXEC sys.sp_posttracertoken 
  @publication = @publication,
  @tracer_token_id = @tokenID OUTPUT;
SELECT 'The ID of the new tracer token is ''' + 
    CONVERT(varchar,@tokenID) + '''.'
GO

-- Wait 10 seconds for the token to make it to the Subscriber.
WAITFOR DELAY '00:00:10';
GO

-- Get latency information for the last inserted token.
DECLARE @publication AS sysname;
DECLARE @tokenID AS int;
SET @publication = N'AdvWorksProductTran'; 

CREATE TABLE #tokens (tracer_id int, publisher_commit datetime)

-- Return tracer token information to a temp table.
INSERT #tokens (tracer_id, publisher_commit)
EXEC sys.sp_helptracertokens @publication = @publication;
SET @tokenID = (SELECT TOP 1 tracer_id FROM #tokens
ORDER BY publisher_commit DESC)
DROP TABLE #tokens

-- Get history for the tracer token.
EXEC sys.sp_helptracertokenhistory 
  @publication = @publication, 
  @tracer_id = @tokenID;
GO

Permisos

Solo los miembros del rol fijo de servidor sysadmin o el rol fijo de base de datos db_owner pueden ejecutar sp_posttracertoken.

Contenido relacionado