Oggetto ResourceLocator

Oggetto che fornisce il percorso di una risorsa. È possibile utilizzare un oggetto ResourceLocator anziché un URI di risorsa nelle operazioni dell'oggetto Session, ad esempio Session.Get, Session.Put o Session.Enumerate.

Questo oggetto consente di:

• Aggiungere uno o più selettori che identificano una particolare istanza di una risorsa. Ciò equivale a fornire un valore di chiave nell'URI della risorsa per una risorsa che usa chiavi. Per altre informazioni, vedere ResourceLocator.AddSelector. È possibile eseguire un'operazione simile usando il parametro di filtro in una chiamata a Session.Enumerate.
• Specificare un percorso di frammento e un dialetto per ottenere una sola proprietà di una risorsa. È anche possibile specificare uno o tutti gli elementi di una proprietà di matrice specificando l'indice della matrice. Per altre informazioni, vedere ResourceLocator.FragmentPath.
• Aggiungere una o più opzioni che un'origine dati può richiedere per elaborare una richiesta. Per altre informazioni, vedere ResourceLocator.AddOption.

Per altre informazioni, vedere Esecuzione di query per istanze specifiche di una risorsa.

Membri

L'oggetto ResourceLocator ha questi tipi di membri:

• Metodi
• Proprietà

Metodi

L'oggetto ResourceLocator dispone di questi metodi.

Proprietà

L'oggetto ResourceLocator ha queste proprietà.

Commenti

L'oggetto ResourceLocator corrisponde all'interfaccia IWSManResourceLocator .

Esempio

Nell'esempio di codice VBScript seguente vengono ottenute le proprietà NumberOfLogicalProcessors e NumberOfCores da un'istanza specifica di Win32_Processor.

Option Explicit
Dim strUri
strUri = "http://schemas.microsoft.com/wbem/wsman/1/" _
    & "wmi/root/cimv2/Win32_Processor"
Const FragmentDialect = _
    "https://www.w3.org/TR/1999/REC-xpath-19991116"

Dim WSMan
Set WSMan = CreateObject("WSMan.Automation")

Dim Session
Set Session = WSMan.CreateSession

Dim Locator
Set Locator = WSMan.CreateResourceLocator(strUri)

Locator.AddSelector "DeviceID", "CPU0"

Dim NumberOfCores_XML
Locator.FragmentPath = "NumberOfCores"
Locator.FragmentDialect = FragmentDialect
NumberOfCores_XML = Session.Get(Locator)
DisplayOutput NumberOfCores_XML

Dim NumberOfLogicalProcessors_XML
Locator.FragmentPath = "NumberOfLogicalProcessors"
Locator.FragmentDialect = FragmentDialect
NumberOfLogicalProcessors_XML = Session.Get(Locator)

DisplayOutput NumberOfLogicalProcessors_XML

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************

Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" )    
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile )           
End Sub

Requisiti

Vedi anche

WinRM Scripting API