Metodo Session.Get

Recupera la risorsa specificata dall'URI e restituisce una rappresentazione XML dell'istanza corrente della risorsa.

Sintassi

Session.Get( _
  ByVal resourceUri, _
  [ ByVal flags ] _
)

Parametri

resourceUri [in]

Identificatore della risorsa da recuperare.

Questo parametro può contenere uno dei seguenti elementi:

• URI con o senza selettori. Quando si chiama il metodo Get con un selettore per ottenere una risorsa WMI, usare la proprietà chiave o le proprietà dell'oggetto. Nell'esempio di codice VBScript (Visual Basic Scripting Edition) seguente, ad esempio, la chiave viene specificata da Win32_Service?Name=winmgmt. Per le classi singleton, ad esempio Win32_LocalTime, non è possibile usare un selettore.

  strResourceUri = "http://schemas.microsoft.com/" _ 
      & "wbem/wsman/1/wmi/root/cimv2/Win32_Service?Name=winmgmt"
  
  strResourceUri = "http://schemas.microsoft.com/" _ 
      & "wbem/wsman/1/wmi/root/cimv2/Win32_LocalTime"
  

• Oggetto ResourceLocator che può contenere selettori, frammenti o opzioni.

• Riferimento all'endpoint di indirizzamento WS , come descritto nello standard del protocollo WS-Management. Per altre informazioni sulla specifica pubblica per WS-Management Protocol, vedere Pagina relativa alle specifiche di gestione.

flag [in, facoltativo]

Riservato. Deve essere 0.

Valore restituito

Rappresentazione XML della risorsa.

Esempio

Nell'esempio di codice VBScript seguente viene recuperata la rappresentazione XML dell'istanza di Win32_Service che rappresenta il servizio Winmgmt WMI nel computer locale.

'Create a WSMan object.
Set objWsman = CreateObject( "WSMAN.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

'Create a Session object.
Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 


strResourceUri = "http://schemas.microsoft.com/" _ 
    & "wbem/wsman/1/wmi/root/cimv2/Win32_Service?Name=winmgmt"

On Error Resume Next
xmlResource = objSession.Get( strResourceUri )
WScript.Echo "Response message: " & Chr(10) & xmlResource
If Err.Number <> 0 Then
    DisplayErrorInfo
End If
On Error Goto 0

Sub DisplayErrorInfo()
    WScript.Echo "An error has occurred."     
    WScript.Echo
    WScript.Echo "Error Info"
    WScript.Echo "-----------"
    WScript.Echo "Number      : 0x" & hex(Err.number)
    WScript.Echo "Description : " & Err.Description
    WScript.Echo "Source      : " & Err.Source
    WScript.Echo "HelpFile    : " & Err.helpfile
    WScript.Echo "HelpContext : " & Err.HelpContext    
    WScript.Echo Err.Clear    
End Sub

Nell'esempio di codice VBScript seguente viene recuperata l'istanza del servizio Winmgmt WMI da un computer remoto. Il computer remoto è identificato dal nome di dominio completo (servername.domain.com). L'unica differenza tra la versione locale e remota è la specifica del computer remoto nella chiamata a WSMan.CreateSession.

Const RemoteComputer = "servername.domain.com"

'Create a WSMan object.
Set objWsman = CreateObject( "WSMAN.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

'Create a Session object.
Dim objSession
Set objSession = objWsman.CreateSession( "https://" & RemoteComputer )
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 


strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/" _ 
    & "Win32_Service?Name=winmgmt"


On Error Resume Next
xmlResource = objSession.Get( strResourceUri )
WScript.Echo "Response message: " & Chr(10) & xmlResource
If Err.Number <> 0 Then
    DisplayErrorInfo
End If
On Error Goto 0

Sub DisplayErrorInfo()
    WScript.Echo "An error has occurred."     
    WScript.Echo
    WScript.Echo "Error Info"
    WScript.Echo "-----------"
    WScript.Echo "Number      : 0x" & hex(Err.number)
    WScript.Echo "Description : " & Err.Description
    WScript.Echo "Source      : " & Err.Source
    WScript.Echo "HelpFile    : " & Err.helpfile
    WScript.Echo "HelpContext : " & Err.HelpContext    
    WScript.Echo Err.Clear    
End Sub

Requisiti

Vedi anche

sessione