OdbcLoggingSection クラス 1

Open Database Connectivity (ODBC) 接続を使って IIS イベントをデータベースにログするための構成設定を指定します。

構文

class OdbcLoggingSection : ConfigurationSection  

メソッド

次の表に、OdbcLoggingSection クラスによって公開されるメソッドの一覧を示します。

プロパティ

次の表は、OdbcLoggingSection クラスによって公開されるプロパティの一覧です。

サブクラス

このクラスにはサブクラスが含まれていません。

解説

ODBC ログを使うと、ローカルの Microsoft Access データベースまたはローカルかリモートの Microsoft SQL Server データベースに IIS データをログできます。

例

次のコード例では、DataSource、Tablename、Username、Password の各プロパティに新しい値を指定します。 ヘルパー関数を使って、変更の前後の値を表示します。

' Connect to the WMI WebAdministration namespace.  
Set oWebAdmin = GetObject( _  
    "winmgmts:root\WebAdministration")  
  
' Get the ODBCLoggingSection.  
Set oSection = oWebAdmin.Get("OdbcLoggingSection.Path=" & _  
    "'MACHINE/WEBROOT/APPHOST',Location=''")  
  
' Display the class name of the section.  
WScript.Echo "[ " & oSection.Path_.Class & " ]"  
  
' Display the initial values.  
Call DisplayValues("Initial Values", oSection)  
  
' Specify new ODBCLoggingSection property values.  
oSection.DataSource = "ODBCLoggingDB"  
oSection.TableName = "ODBCLoggingTable"  
oSection.Username = "ODBCLoggingAdmin"  
oSection.Password = "ODBCLoggingPassword"  
  
' Save the values to configuration.  
oSection.Put_  
  
' Refresh the oSection object variable with the new values.  
oSection.Refresh_  
  
' Show the changed values.  
Call DisplayValues("New Values", oSection)  
  
' ==== DisplayValues helper function. ====  
Function DisplayValues(HeadingText, oSection)  
    ' Display a heading.  
    WScript.Echo  
    WScript.Echo HeadingText  
    WScript.Echo String(Len(HeadingText), "-")  
  
    ' Display section properties.  
    WScript.Echo "Path: " & oSection.Path  
    WScript.Echo "Location: " & oSection.Location  
    WScript.Echo "DataSource: " & oSection.DataSource  
    WScript.Echo "TableName: " & oSection.TableName  
    WScript.Echo "Username: " & oSection.Username  
    WScript.Echo "Password: " & oSection.Password  
End Function  
  

継承階層

ConfigurationSection

OdbcLoggingSection

要件

参照

CentralBinaryLogFile クラス
CentralW3CLogFile クラス
ConfigurationSection クラス
HttpLoggingSection クラス
LogSection クラス
SiteLogFile クラス
IIS で ODBC ログを構成する方法