ERROR_PROCEDURE (Transact-SQL)

[アーティクル]
12/16/2008

TRY...CATCH 構造の CATCH ブロックの実行原因となったエラーが発生した、ストアドプロシージャまたはトリガの名前を返します。

構文

ERROR_PROCEDURE()

戻り値の型

nvarchar(126)

戻り値

CATCH ブロックで呼び出された場合、エラーが発生したストアドプロシージャ名を返します。

ストアドプロシージャまたはトリガ内でエラーが発生しなかった場合は NULL を返します。

CATCH ブロックの範囲外で呼び出された場合は NULL を返します。

解説

ERROR_PROCEDURE は、CATCH ブロックのスコープ内であればどこでも呼び出すことができます。

ERROR_PROCEDURE は、呼び出される回数や CATCH ブロックのスコープのどこで呼び出されるかに関係なく、エラーが発生したストアドプロシージャまたはトリガの名前を返します。これは @@ERROR のような関数とは対称的です。@@ERROR 関数では、エラーの発生元となるステートメントの直後にあるステートメント、または CATCH ブロックの最初のステートメントのエラー番号が返されます。

入れ子にされた CATCH ブロックを使用すると、ERROR_PROCEDURE では、参照される CATCH ブロックのスコープに固有のストアドプロシージャまたはトリガの名前が返されます。たとえば、TRY...CATCH 構造の CATCH ブロックには、TRY...CATCH が入れ子にされている場合があり、入れ子にされた CATCH ブロック内では、ERROR_PROCEDURE によって、入れ子にされた CATCH ブロックを起動した、エラーの発生元となるストアドプロシージャまたはトリガの名前が返されます。ERROR_PROCEDURE が外側の CATCH ブロックで実行された場合は、外側の CATCH ブロックを起動した、エラーの発生元となるストアドプロシージャまたはトリガの名前が返されます。

例

A. CATCH ブロックで ERROR_PROCEDURE を使用する

次の例では、0 除算エラーを生成したストアドプロシージャを示します。ERROR_PROCEDURE ではエラーが発生したストアドプロシージャの名前が返されます。

USE AdventureWorks;
GO

-- Verify that the stored procedure does not already exist.
IF OBJECT_ID ( 'usp_ExampleProc', 'P' ) IS NOT NULL 
    DROP PROCEDURE usp_ExampleProc;
GO

-- Create a stored procedure that 
-- generates a divide-by-zero error.
CREATE PROCEDURE usp_ExampleProc
AS
    SELECT 1/0;
GO

BEGIN TRY
    -- Execute the stored procedure inside the TRY block.
    EXECUTE usp_ExampleProc;
END TRY
BEGIN CATCH
    SELECT ERROR_PROCEDURE() AS ErrorProcedure;
END CATCH;
GO

B. CATCH ブロックで、別のエラー処理ツールと一緒に ERROR_PROCEDURE を使用する

次の例では、0 除算エラーを生成したストアドプロシージャを示します。ここではエラー発生元のストアドプロシージャの名前と共に、エラーに関連する情報が返されます。

USE AdventureWorks;
GO

-- Verify that the stored procedure does not already exist.
IF OBJECT_ID ( 'usp_ExampleProc', 'P' ) IS NOT NULL 
    DROP PROCEDURE usp_ExampleProc;
GO

-- Create a stored procedure that 
-- generates a divide-by-zero error.
CREATE PROCEDURE usp_ExampleProc
AS
    SELECT 1/0;
GO

BEGIN TRY
    -- Execute the stored procedure inside the TRY block.
    EXECUTE usp_ExampleProc;
END TRY
BEGIN CATCH
    SELECT 
        ERROR_NUMBER() AS ErrorNumber,
        ERROR_SEVERITY() AS ErrorSeverity,
        ERROR_STATE() AS ErrorState,
        ERROR_PROCEDURE() AS ErrorProcedure,
        ERROR_MESSAGE() AS ErrorMessage,
        ERROR_LINE() AS ErrorLine;
        END CATCH;
GO

参照

その他の技術情報

Transact-SQL のエラー情報の取得
 Transact-SQL での TRY...CATCH の使用
 RAISERROR の使用
 データベースエンジンエラーの重大度

ヘルプおよび情報

SQL Server 2005 の参考資料の入手

次の方法で共有