@@ERROR (Transact-SQL)

[アーティクル]
12/16/2008

最後に実行した Transact-SQL ステートメントのエラー番号を返します。

構文

@@ERROR

戻り値の型

integer

解説

直前の Transact-SQL ステートメントでエラーが発生しなかった場合は、0 が返されます。

直前のステートメントでエラーが発生した場合は、エラー番号が返されます。エラーが sys.messages カタログビューのエラーであった場合、そのエラーに対応する sys.messages.message_id 列の値が @@ERROR に含まれます。@@ERROR エラー番号に関連付けられているテキストは、sys.messages で表示できます。

各ステートメントの実行時に @@ERROR はクリアおよびリセットされるので、ステートメントの検証を行った直後にこの変数の値を調べるか、または後で調べることができるようローカル変数に保存してください。

SQL Server 2005 データベースエンジンではエラーの処理に TRY...CATCH 構造が導入されました。TRY...CATCH 構造では、その他のシステム関数 (ERROR_LINE、ERROR_MESSAGE、ERROR_PROCEDURE、ERROR_SEVERITY、ERROR_STATE) もサポートされます。これらの関数では、@ERROR よりも多くのエラー情報が返されます。また、ERROR_NUMBER 関数もサポートされます。この関数では、エラーが発生したステートメントの直後のステートメントでエラー番号を返すなどの操作を行えます。詳細については、「TRY...CATCH (Transact-SQL)」を参照してください。

例

A. @@ERROR を使用して特定のエラーを検出する

次の例では、@@ERROR を使用して、UPDATE ステートメントに CHECK 制約の違反 (エラー #547) がないかどうかを調べます。

USE AdventureWorks;
GO
UPDATE HumanResources.Employee 
    SET PayFrequency = 4
    WHERE NationalIDNumber = 615389812;
IF @@ERROR = 547
    PRINT N'A check constraint violation occurred.';
GO

B. @@ERROR を使用して条件的にプロシージャを終了する

次の例では、ストアドプロシージャ内で INSERT ステートメントを実行した後、IF...ELSE ステートメントにより @@ERROR の値を調べます。@@ERROR 変数の値は、呼び出し元のプログラムに返される戻り値として採用され、プロシージャ実行の成否を示します。

USE AdventureWorks;
GO
-- Drop the procedure if it already exists.
IF OBJECT_ID(N'HumanResources.usp_DeleteCandidate', N'P')
             IS NOT NULL
    DROP PROCEDURE HumanResources.usp_DeleteCandidate;
GO
-- Create the procedure.
CREATE PROCEDURE HumanResources.usp_DeleteCandidate 
    @CandidateID INT
AS
-- Execute the DELETE statement.
DELETE FROM HumanResources.JobCandidate
    WHERE JobCandidateID = @CandidateID;
-- Test the error value.
IF @@ERROR <> 0 
    BEGIN
        -- Return 99 to the calling program to indicate failure.
        PRINT N'An error occurred deleting the candidate information.';
        RETURN 99;
    END
ELSE
    BEGIN
        -- Return 0 to the calling program to indicate success.
        PRINT N'The job candidate has been deleted.';
        RETURN 0;
    END;
GO

C. @@ERROR と @@ROWCOUNT を使用する

次の例では、@@ROWCOUNT と @@ERROR を使用して、UPDATE ステートメント操作の有効性の検査を行います。ここでは、@@ERROR の値でエラーがないかどうかを調べ、@@ROWCOUNT を使用して、テーブルの行を正しく更新できたかどうかを確認します。

USE AdventureWorks;
GO
IF OBJECT_ID(N'Purchasing.usp_ChangePurchaseOrderHeader',N'P')
             IS NOT NULL
   DROP PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader;
GO
CREATE PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader
    @PurchaseOrderID INT, 
    @EmployeeID INT
AS
-- Declare variables used in error checking.
DECLARE @ErrorVar INT, 
    @RowCountVar INT;

-- Execute the UPDATE statement.
UPDATE PurchaseOrderHeader 
    SET EmployeeID = @EmployeeID 
    WHERE PurchaseOrderID = @PurchaseOrderID;

-- Save the @@ERROR and @@ROWCOUNT values in local 
-- variables before they are cleared.
SELECT @ErrorVar = @@ERROR, 
    @RowCountVar = @@ROWCOUNT;

-- Check for errors. If an invalid @EmployeeID was specified
-- the UPDATE statement returns a foreign-key violation error #547.
IF @ErrorVar <> 0
    BEGIN
        IF @ErrorVar = 547
            BEGIN
                PRINT N'ERROR: Invalid ID specified for new employee.';
                RETURN 1;
            END
        ELSE
            BEGIN
                PRINT N'ERROR: error '
                    + RTRIM(CAST(@ErrorVar AS NVARCHAR(10)))
                    + N' occurred.';
                RETURN 2;
            END
    END

-- Check the row count. @RowCountVar is set to 0 
-- if an invalid @PurchaseOrderID was specified.
IF @RowCountVar = 0
    BEGIN
        PRINT 'Warning: The EmployeeID specified is not valid';
        RETURN 1;
    END
ELSE
    BEGIN
        PRINT 'Purchase order updated with the new employee';
        RETURN 0;
    END;
GO

参照

その他の技術情報

データベースエンジンエラーの処理
 @@ERROR の使用
 Transact-SQL での TRY...CATCH の使用

ヘルプおよび情報

SQL Server 2005 の参考資料の入手

次の方法で共有