Event ステートメント

ユーザー定義のイベントを宣言します。

[ <attrlist> ] [ accessmodifier ] _
[ Shared ] [ Shadows ] Event eventname[(parameterlist)] _
[ Implements implementslist ]
' -or-
[ <attrlist> ] [ accessmodifier ] _
[ Shared ] [ Shadows ] Event eventname As delegatename _
[ Implements implementslist ]
' -or-
 [ <attrlist> ] [ accessmodifier ] _
[ Shared ] [ Shadows ] Custom Event eventname As delegatename _
[ Implements implementslist ]
   [ <attrlist> ] AddHandler(ByVal value As delegatename)
      [ statements ]
   End AddHandler
   [ <attrlist> ] RemoveHandler(ByVal value As delegatename)
      [ statements ]
   End RemoveHandler
   [ <attrlist> ] RaiseEvent(delegatesignature)
      [ statements ]
   End RaiseEvent
End Event

指定項目

解説

宣言したイベントは、RaiseEvent ステートメントを使って発生させます。 通常、イベントの宣言と発生は、次のように行われます。

Public Class EventSource
    ' Declare an event.
    Public Event LogonCompleted(ByVal UserName As String)
    Sub CauseEvent()
        ' Raise an event on successful logon.
        RaiseEvent LogonCompleted("AustinSteele")
    End Sub
End Class

イベントを処理するためには、Handles ステートメントまたは AddHandler ステートメントを使用して、イベント ハンドラーをイベントに関連付ける必要があります。 サブルーチンとイベントのシグネチャは一致していることが必要です。 共有イベントを処理するには、AddHandler ステートメントを使う必要があります。

Event は、モジュール レベルでのみ使用できます。 つまり、イベントの宣言コンテキストは、クラス、構造体、モジュール、またはインターフェイスであることが必要で、ソース ファイル、名前空間、プロシージャ、ブロックでは宣言できません。 詳細については、「宣言コンテキストと既定のアクセス レベル (Visual Basic)」を参照してください。

ほとんどの状況で、このトピックの「構文」のセクションにある最初の構文を使ってイベントを宣言できますが、 一部のシナリオでは、イベントの動作をより詳細に制御することが必要になります。 このトピックの「構文」セクションの最後に Custom キーワードを使用した構文がありますが、これを使用すると、カスタム イベントを定義してイベントを詳細に制御できます。 カスタム イベントでは、コードでイベント ハンドラーを追加または削除するときに、つまりコードでイベントを生成するときに、何が起こるかを正確に指定します。 使用例については、「方法: カスタム イベントを宣言してメモリを節約する (Visual Basic)」および「方法: カスタム イベントを宣言してブロックを回避する (Visual Basic)」を参照してください。

使用例

次の例では、イベントを使用して 10 秒から 0 秒までカウントダウンします。 このコードは、イベント関連のいくつかのメソッド、プロパティ、およびステートメントの例を示しています。 RaiseEvent ステートメントの使用例も含まれています。

イベントを発生させるクラスをイベント ソース、イベントを処理するメソッドをイベント ハンドラーと呼びます。 イベント ソースには、そこで生成される複数のイベント ハンドラーを設定できます。 クラスでイベントが発生すると、そのイベントは、オブジェクトのインスタンスに対するイベントを処理するために選択されたすべてのクラスで発生します。

また、この例では、ボタン (Button1) とテキスト ボックス (TextBox1) を含んだフォーム (Form1) を使用します。 ボタンをクリックすると、1 つ目のテキスト ボックスに 10 秒から 0 秒までのカウントダウンが表示されます。 カウントダウンが終わると (10 秒が経過すると)、1 つ目のテキスト ボックスに "Done" と表示されます。

Form1 のコードでは、フォームの初期状態と終了状態を指定します。 イベント発生時に実行されるコードも含まれます。

この例を使用するには、新しい Windows Forms プロジェクトを開きます。 次に、Button1 という名前のボタンと TextBox1 という名前のテキスト ボックスを、Form1 という名前のメイン フォームに追加します。 続いてフォームを右クリックし、[コードの表示] をクリックして、コード エディターを開きます。

Form1 クラスの宣言セクションに、WithEvents 変数を追加します。

Private WithEvents mText As TimerState

Form1 のコードに以下のコードを追加します。 Form_Load や Button_Click など、重複して存在する可能性のあるプロシージャを置き換えます。

Private Sub Form1_Load() Handles MyBase.Load
    Button1.Text = "Start"
    mText = New TimerState
End Sub
Private Sub Button1_Click() Handles Button1.Click
    mText.StartCountdown(10.0, 0.1)
End Sub

Private Sub mText_ChangeText() Handles mText.Finished
    TextBox1.Text = "Done"
End Sub

Private Sub mText_UpdateTime(ByVal Countdown As Double
  ) Handles mText.UpdateTime

    TextBox1.Text = Format(Countdown, "##0.0")
    ' Use DoEvents to allow the display to refresh.
    My.Application.DoEvents()
End Sub

Class TimerState
    Public Event UpdateTime(ByVal Countdown As Double)
    Public Event Finished()
    Public Sub StartCountdown(ByVal Duration As Double, 
                              ByVal Increment As Double)
        Dim Start As Double = DateAndTime.Timer
        Dim ElapsedTime As Double = 0

        Dim SoFar As Double = 0
        Do While ElapsedTime < Duration
            If ElapsedTime > SoFar + Increment Then
                SoFar += Increment
                RaiseEvent UpdateTime(Duration - SoFar)
            End If
            ElapsedTime = DateAndTime.Timer - Start
        Loop
        RaiseEvent Finished()
    End Sub
End Class

F5 キーを押して上のコード例を実行し、"Start" というラベルのボタンをクリックしてください。 最初のテキスト ボックスが、秒のカウント ダウンを開始します。 カウント時間 (10 秒) が経過すると、最初のテキスト ボックスに "Done" と表示されます。

参照

処理手順

方法: カスタム イベントを宣言してメモリを節約する (Visual Basic)

方法: カスタム イベントを宣言してブロックを回避する (Visual Basic)

参照

RaiseEvent ステートメント

Implements ステートメント

AddHandler ステートメント

RemoveHandler ステートメント

Handles 句 (Visual Basic)

Delegate ステートメント

Shared (Visual Basic)

Shadows (Visual Basic)

概念

イベント (Visual Basic)