Solucionar problemas com consultas de diagnóstico avançadas para o Azure Cosmos DB for MongoDB

Artigo
08/15/2024

APLICA-SE AO: NoSQL MongoDB Cassandra Gremlin

Neste artigo, veremos como escrever consultas mais avançadas para ajudar a solucionar problemas de sua conta do Azure Cosmos DB usando os logs de diagnóstico enviados às tabelas do Diagnóstico do Azure (herdado) e específicas dos recursos (versão prévia) .

Para as tabelas do Diagnóstico do Azure, todos os dados são gravados em uma única tabela. Os usuários especificam a categoria que desejam consultar. Se você quiser exibir a consulta de texto completo de sua solicitação, consulte Monitore dados do Azure Cosmos DB usando configurações de diagnóstico no Azure para saber como habilitar esse recurso.

Para tabelas específicas dos recursos, os dados são gravados em tabelas individuais para cada categoria do recurso. Recomendamos esse modo porque:

Facilita o trabalho com os dados.
Fornece melhor detectabilidade dos esquemas.
Melhora o desempenho entre a latência de ingestão e os tempos de consulta.

Consultas comuns

Consultas comuns são mostradas nas tabelas específicas do recurso e do Diagnóstico do Azure.

As N(10) principais RU (unidades de solicitação) que consomem solicitações ou consultas em um período específico

Específico de recursos
Diagnóstico do Azure

//Enable full-text query to view entire query text
CDBMongoRequests
| where TimeGenerated > ago(24h)
| project PIICommandText, ActivityId, DatabaseName , CollectionName, RequestCharge
| order by RequestCharge desc
| take 10

AzureDiagnostics
| where Category == "MongoRequests"
| where TimeGenerated > ago(24h)
| project piiCommandText_s, activityId_g, databaseName_s , collectionName_s, requestCharge_s
| order by requestCharge_s desc
| take 10

Solicitações limitadas (statusCode = 429 ou 16500) em uma janela de tempo específica

Específico de recursos
Diagnóstico do Azure

CDBMongoRequests
| where TimeGenerated > ago(24h)
| where ErrorCode == "429" or ErrorCode == "16500"
| project DatabaseName, CollectionName, PIICommandText, OperationName, TimeGenerated

AzureDiagnostics
| where Category == "MongoRequests" and TimeGenerated > ago(24h)
| where ErrorCode == "429" or ErrorCode == "16500"
| project databaseName_s , collectionName_s , piiCommandText_s , OperationName, TimeGenerated

Solicitações que atingiram o tempo limite (statusCode = 50) em uma janela de tempo específica

Específico de recursos
Diagnóstico do Azure

CDBMongoRequests
| where TimeGenerated > ago(24h)
| where ErrorCode == "50"
| project DatabaseName, CollectionName, PIICommandText, OperationName, TimeGenerated

AzureDiagnostics
| where Category == "MongoRequests" and TimeGenerated > ago(24h)
| where ErrorCode == "50"
| project databaseName_s , collectionName_s , piiCommandText_s , OperationName, TimeGenerated

Consultas com comprimentos de resposta grandes (tamanho do conteúdo da resposta do servidor)

Específico de recursos
Diagnóstico do Azure

CDBMongoRequests
//specify collection and database
//| where DatabaseName == "DB NAME" and CollectionName == "COLLECTIONNAME"
| summarize max(ResponseLength) by PIICommandText, RequestCharge, DurationMs, OperationName, TimeGenerated
| order by max_ResponseLength desc

AzureDiagnostics
| where Category == "MongoRequests"
//specify collection and database
//| where databaseName_s == "DB NAME" and collectionName_s == "COLLECTIONNAME"
| summarize max(responseLength_s) by piiCommandText_s, OperationName, duration_s, requestCharge_s
| order by max_responseLength_s desc

Consumo de RU por partição física (em todas as réplicas no conjunto de réplicas)

Específico de recursos
Diagnóstico do Azure

CDBPartitionKeyRUConsumption
| where TimeGenerated >= now(-1d)
//specify collection and database
//| where DatabaseName == "DB NAME" and CollectionName == "COLLECTIONNAME"
// filter by operation type
//| where operationType_s == 'Create'
| summarize sum(todouble(RequestCharge)) by toint(PartitionKeyRangeId)
| render columnchart

AzureDiagnostics
| where TimeGenerated >= now(-1d)
| where Category == 'PartitionKeyRUConsumption'
//specify collection and database
//| where databaseName_s == "DB NAME" and collectionName_s == "COLLECTIONNAME"
// filter by operation type
//| where operationType_s == 'Create'
| summarize sum(todouble(requestCharge_s)) by toint(partitionKeyRangeId_s)
| render columnchart

Consumo de RU por partição lógica (em todas as réplicas no conjunto de réplicas)

Específico de recursos
Diagnóstico do Azure

CDBPartitionKeyRUConsumption
| where TimeGenerated >= now(-1d)
//specify collection and database
//| where DatabaseName == "DB NAME" and CollectionName == "COLLECTIONNAME"
// filter by operation type
//| where operationType_s == 'Create'
| summarize sum(todouble(RequestCharge)) by PartitionKey, PartitionKeyRangeId
| render columnchart

AzureDiagnostics
| where TimeGenerated >= now(-1d)
| where Category == 'PartitionKeyRUConsumption'
//specify collection and database
//| where databaseName_s == "DB NAME" and collectionName_s == "COLLECTIONNAME"
// filter by operation type
//| where operationType_s == 'Create'
| summarize sum(todouble(requestCharge_s)) by partitionKey_s, partitionKeyRangeId_s
| render columnchart

Próximas etapas

Para saber mais sobre como criar configurações de diagnóstico para o Azure Cosmos DB, consulte Criar configurações de diagnóstico.
Para obter mais detalhes sobre como criar uma configuração de diagnóstico usando o portal do Azure, a CLI do Azure ou o PowerShell, consulte Criar configurações de diagnóstico para coletar logs e métricas de plataforma no Azure.

Compartilhar via