Assíncrono (Visual Basic)

  • Artigo

O Async modificador indica que o método ou expressão lambda que ele modifica é assíncrono. Esses métodos são referidos como métodos assíncronos.

Um método assíncrono fornece uma maneira conveniente de fazer um trabalho potencialmente de longa duração sem bloquear o thread do chamador. O chamador de um método assíncrono pode retomar seu trabalho sem esperar que o método assíncrono seja concluído.

Nota

As Async palavras-chave e Await foram introduzidas no Visual Studio 2012. Para obter uma introdução à programação assíncrona, consulte Programação assíncrona com Async e Await.

O exemplo a seguir mostra a estrutura de um método assíncrono. Por convenção, os nomes de método assíncrono terminam em "Async".

Public Async Function ExampleMethodAsync() As Task(Of Integer)
    ' . . .

    ' At the Await expression, execution in this method is suspended and,
    ' if AwaitedProcessAsync has not already finished, control returns
    ' to the caller of ExampleMethodAsync. When the awaited task is
    ' completed, this method resumes execution.
    Dim exampleInt As Integer = Await AwaitedProcessAsync()

    ' . . .

    ' The return statement completes the task. Any method that is
    ' awaiting ExampleMethodAsync can now get the integer result.
    Return exampleInt
End Function

Normalmente, um método modificado pela Async palavra-chave contém pelo menos uma expressão ou instrução Await . O método é executado de forma síncrona até atingir o primeiro Await, momento em que é suspenso até que a tarefa aguardada seja concluída. Enquanto isso, o controle é retornado ao chamador do método. Se o método não contiver uma Await expressão ou instrução, o método não será suspenso e será executado como um método síncrono. Um aviso do compilador alerta você para quaisquer métodos assíncronos que não contenham Await porque essa situação pode indicar um erro. Para obter mais informações, consulte o erro do compilador.

A Async palavra-chave é uma palavra-chave sem reservas. É uma palavra-chave quando modifica um método ou uma expressão lambda. Em todos os outros contextos, é interpretado como um identificador.

Tipos de devolução

Um método assíncrono é um procedimento Sub ou um procedimento Function que tem um tipo de retorno de Task ou Task<TResult>. O método não pode declarar nenhum parâmetro ByRef .

Você especifica Task(Of TResult) para o tipo de retorno de um método assíncrono se a instrução Return do método tiver um operando do tipo TResult. Você usa Task se nenhum valor significativo for retornado quando o método for concluído. Ou seja, uma chamada para o método retorna um Task, mas quando o Task é concluído, qualquer Await instrução que está aguardando o Task não produz um valor de resultado.

As sub-rotinas assíncronas são usadas principalmente para definir manipuladores de eventos onde um Sub procedimento é necessário. O chamador de uma sub-rotina assíncrona não pode esperar e não pode detetar exceções que o método lança.

Para obter mais informações e exemplos, consulte Tipos de retorno assíncronos.

Exemplo

Os exemplos a seguir mostram um manipulador de eventos assíncrono, uma expressão lambda assíncrona e um método assíncrono. Para obter um exemplo completo que usa esses elementos, consulte Passo a passo: acessando a Web usando Async e Await. Você pode baixar o exemplo do navegador de exemplo .NET. O código de exemplo está no projeto SerialAsyncExample .

' An event handler must be a Sub procedure.
Async Sub button1_Click(sender As Object, e As RoutedEventArgs) Handles button1.Click
    textBox1.Clear()
    ' SumPageSizesAsync is a method that returns a Task.
    Await SumPageSizesAsync()
    textBox1.Text = vbCrLf & "Control returned to button1_Click."
End Sub

' The following async lambda expression creates an equivalent anonymous
' event handler.
AddHandler button1.Click, Async Sub(sender, e)
                              textBox1.Clear()
                              ' SumPageSizesAsync is a method that returns a Task.
                              Await SumPageSizesAsync()
                              textBox1.Text = vbCrLf & "Control returned to button1_Click."
                          End Sub

' The following async method returns a Task(Of T).
' A typical call awaits the Byte array result:
'      Dim result As Byte() = Await GetURLContents("https://msdn.com")
Private Async Function GetURLContentsAsync(url As String) As Task(Of Byte())

    ' The downloaded resource ends up in the variable named content.
    Dim content = New MemoryStream()

    ' Initialize an HttpWebRequest for the current URL.
    Dim webReq = CType(WebRequest.Create(url), HttpWebRequest)

    ' Send the request to the Internet resource and wait for
    ' the response.
    Using response As WebResponse = Await webReq.GetResponseAsync()
        ' Get the data stream that is associated with the specified URL.
        Using responseStream As Stream = response.GetResponseStream()
            ' Read the bytes in responseStream and copy them to content.
            ' CopyToAsync returns a Task, not a Task<T>.
            Await responseStream.CopyToAsync(content)
        End Using
    End Using

    ' Return the result as a byte array.
    Return content.ToArray()
End Function

Consulte também