IteratorStateMachineAttribute Класс

Определение

public ref class IteratorStateMachineAttribute sealed : System::Runtime::CompilerServices::StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)]
[System.Serializable]
public sealed class IteratorStateMachineAttribute : System.Runtime.CompilerServices.StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

[<System.AttributeUsage(System.AttributeTargets.Method, AllowMultiple=false, Inherited=false)>]
[<System.Serializable>]
type IteratorStateMachineAttribute = class
    inherit StateMachineAttribute

Public NotInheritable Class IteratorStateMachineAttribute
Inherits StateMachineAttribute

Наследование

Object

Attribute

StateMachineAttribute

IteratorStateMachineAttribute

Атрибуты

AttributeUsageAttribute SerializableAttribute

Примеры

В следующем примере показано, как определить, является ли метод методом итератора. В этом примере выполняется следующее IsIteratorMethod :

• Получает MethodInfo объект для имени метода с помощью Type.GetMethod.

• Получает Type объект для атрибута с помощью оператора GetType.

• Получает объект атрибута для метода и типа атрибута с помощью MethodInfo.GetCustomAttribute. Если GetCustomAttribute возвращает значение Nothing (Visual Basic), метод не содержит атрибут .

Imports System.Collections.Generic
Imports System.Reflection
Imports System.Threading.Tasks
Imports System.Runtime.CompilerServices


Module Module1

    ' This class is used by the code below to discover method attributes.
    Public Class TheClass
        Public Async Function AsyncMethod() As Task(Of Integer)
            Await Task.Delay(5)
            Return 1
        End Function

        Public Iterator Function IteratorMethod() As IEnumerable(Of Integer)
            Yield 1
            Yield 2
        End Function

        Public Function RegularMethod() As Integer
            Return 0
        End Function
    End Class


    Private Function IsAsyncMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(AsyncStateMachineAttribute)

        Dim attrib = CType(method.GetCustomAttribute(attType), AsyncStateMachineAttribute)
        ' The above variable contains the StateMachineType property.

        Return (attrib IsNot Nothing)
    End Function

    Private Function IsIteratorMethod(classType As Type, methodName As String)
        ' Obtain the method with the specified name.
        Dim method As MethodInfo = classType.GetMethod(methodName)

        Dim attType As Type = GetType(IteratorStateMachineAttribute)

        ' Obtain the custom attribute for the method.
        ' The value returned contains the StateMachineType property.
        ' Nothing is returned if the attribute isn't present for the method.
        Dim attrib = CType(method.GetCustomAttribute(attType), IteratorStateMachineAttribute)

        Return (attrib IsNot Nothing)
    End Function

    Private Sub ShowResult(classType As Type, methodName As String)
        Console.Write((methodName & ": ").PadRight(16))

        If IsAsyncMethod(classType, methodName) Then
            Console.WriteLine("Async method")
        ElseIf IsIteratorMethod(classType, methodName) Then
            Console.WriteLine("Iterator method")
        Else
            Console.WriteLine("Regular method")
        End If

        ' Note: The IteratorStateMachineAttribute applies to Visual Basic methods
        ' but not C# methods.
    End Sub

    Sub Main()
        ShowResult(GetType(TheClass), "AsyncMethod")
        ShowResult(GetType(TheClass), "IteratorMethod")
        ShowResult(GetType(TheClass), "RegularMethod")

        Console.ReadKey()
    End Sub

    '   AsyncMethod:    Async method
    '   IteratorMethod: Iterator method
    '   RegularMethod:  Regular method

End Module

Комментарии

Атрибут не следует применять IteratorStateMachine к методам в коде. Для методов в Visual Basic с модификатором Итератора компилятор применит IteratorStateMachine атрибут в испускаемом им il-коде.

Если метод (Имя_метода) в Visual Basic имеет модификатор Iterator , компилятор выдает il, включающий структуру конечного автомата. Эта структура содержит код в методе . Этот IL также содержит метод заглушки (Имя_метода), который вызывает конечный автомат. Компилятор добавляет атрибут в IteratorStateMachine метод заглушки, чтобы средства могли идентифицировать соответствующий конечный автомат. Сведения о выдаваемом IL могут измениться в будущих выпусках компиляторов.

Метод итератора выполняет пользовательскую итерацию по коллекции с помощью инструкции Yield (Visual Basic) для возврата каждого элемента по одному за раз. Дополнительные сведения см. в разделе Итераторы.

Конструкторы

Свойства

Методы

Явные реализации интерфейса

Применяется к

См. также раздел

• AsyncStateMachineAttribute
• StateMachineType