ACSAuthIncomingOperations tablosu için sorgular

  • Makale

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

Ayrı kimlik doğrulama işlemlerini listeleme

Kimlik doğrulama işleminin ve sürüm çiftlerinin tüm farklı birleşimlerini döndürür.

ACSAuthIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Kimlik doğrulama işlemi süre yüzdebirlik dilimlerini hesaplama

Her kimlik doğrulama işlemi için çalıştırma süresinin 90., 95. ve 99. yüzdebirlik dilimlerini milisaniye cinsinden hesaplar. Tek bir işlem veya diğer yüzdebirlik değerler için çalıştırılacak şekilde özelleştirilebilir.

ACSAuthIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

Kimlik doğrulama işlemi başına en iyi 5 IP adresi

Her kimlik doğrulama işlemi için, bu işlemi en çok çağıran 5 IP adresini getirin.

ACSAuthIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

Kimlik doğrulama işlem hataları

Her kimlik doğrulama hatasını recency tarafından sıralanmış olarak listeleyin.

ACSAuthIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

Kimlik doğrulama işlemi sonuç sayıları

Her kimlik doğrulama işlemi için döndürülen sonuç türlerini sayın.

ACSAuthIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100