AEWComputePipelinesLogs tablosu için sorgular

  • Makale

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

AEWComputePipelinesLogs günlük görev sayısını alır

Seçili zaman aralığındaki işlem işlem hattı kayıtlarından günlük görev sayısını alın.

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestSucceeded" or EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| summarize Count = count() by Date = bin(TimeGenerated, 1d), ExperimentationGroup = tostring(Properties.ExperimentationGroup)
| sort by Date

AEWComputePipelinesLogs başarısız görevlerin ayrıntılarını alır

Seçilen zaman aralığındaki işlem işlem hatları kayıtlarından en son 100 başarısız görev ayrıntısı alın.

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| project
    TimeGenerated
    ,EventName
    ,ExperimentationGroup = Properties.ExperimentationGroup
    ,AnalysisType = Properties.AnalysisType
| sort by TimeGenerated desc
| take 100

AEWComputePipelinesLogs uzun süre çalışan işleri alır

Son yedi gün içinde işlem işlem hattı kayıtlarından uzun süre çalışan işler alın.

AEWComputePipelinesLogs
| where EventName =~ "CosmosJobUtilization"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| where todouble(Properties.JobRunningInSeconds) >= 24 * 60 * 60
| project
    TimeGenerated
    ,EventName
    ,ExperimentationGroup = Properties.ExperimentationGroup
    ,AnalysisType = Properties.AnalysisType
| sort by TimeGenerated desc

AEWComputePipelinesLogs görevi E2E gecikme süresi alıyor

Seçilen zaman aralığında işlem işlem hatları kayıtlarının E2E gecikme süresini alma görevi.

AEWComputePipelinesLogs
| where EventName =~ "ScorecardRequestSucceeded" or EventName =~ "ScorecardRequestFailed"
| where Properties.ExperimentationGroup =~ "test~ExperimentationGroup"
| summarize
  ScorecardRequestTimeInHoursP99 = percentile(todouble(Properties.ScorecardProcessingInSeconds) / 60 / 60, 99)
  ,ScorecardRequestTimeInHoursAvg = avg(todouble(Properties.ScorecardProcessingInSeconds) / 60 / 60)
  by Date = bin(TimeGenerated, 1d), ExperimentationGroup = tostring(Properties.ExperimentationGroup)
| sort by Date, ExperimentationGroup