ApiManagementGatewayLogs tablosu için sorgular
Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.
İstek sayısı
Son 24 saat içindeki tüm API'ler genelindeki toplam çağrı sayısını sayın.
//Total number of call per resource
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize count(CorrelationId) by _ResourceId
Son 100 çağrının günlükleri
Son 24 saat içindeki en son 100 aramanın günlüklerini alın.
ApiManagementGatewayLogs
| top 100 by TimeGenerated desc
API'lere göre çağrı sayısı
Son 24 saat içinde API başına çağrı sayısını görüntüleyin.
//Calls by API ID
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize count(CorrelationId) by ApiId
Tüketilen bant genişliği
Son 24 saatte tüketilen toplam bant genişliği.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| extend bandwidth = RequestSize + ResponseSize
| summarize sum(bandwidth) by bin(TimeGenerated, 15m), _ResourceId
| render timechart
İstek boyutları
Son 24 saat içindeki istek boyutlarının istatistikleri.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(RequestSize), Median=percentile(RequestSize, 50), 90th_Percentile=percentile(RequestSize, 90) by bin(TimeGenerated, 5m)
| render timechart
Yanıt boyutları
Son 24 saat içindeki yanıt boyutlarının istatistikleri.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(ResponseSize), Median=percentile(ResponseSize, 50), 90th_Percentile=percentile(ResponseSize, 90) by bin(TimeGenerated, 5m)
| render timechart
İstemci TLS sürümleri
Son 24 saat içindeki istemci TLS sürümlerinin dökümü.
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize count(CorrelationId) by ClientTlsVersion, _ResourceId
Hata nedenleri dökümü
Son 24 saat içindeki tüm hata nedenlerinin dökümü.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| summarize count(CorrelationId) by LastErrorReason, _ResourceId
Son 100 başarısız istek
Son 100 başarısız isteğin günlüklerini alın.
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| top 100 by TimeGenerated desc| where ResponseCode >= 400
Arka uçla ilgili sorunlar nedeniyle başarısız istekleri alma
Arka uç sorunları nedeniyle başarısız isteklerin günlüklerini alın.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| where BackendResponseCode >= 400
Arka uçla ilgili olmayan sorunlardan dolayı başarısız istekleri alma
Arka uçla ilgili olmayan sorunlar nedeniyle başarısız isteklerin günlüklerini alın (örneğin, API Yönetim ilkeleri yapılandırması, hız sınırı aşıldı, istemci bağlantısı kesildi).
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| where IsRequestSuccess == false
| where isnull(BackendResponseCode) or BackendResponseCode < 400
| where ResponseCode >= 400
Genel gecikme süresi
API Mangement'ın bir istek almaya başlaması ve API Management'ın yanıtı istemciye geri göndermeyi bitirmesi arasındaki genel gecikme süresi (milisaniye cinsinden) istatistikleri.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(TotalTime), Median=percentile(TotalTime, 50), 90th_Percentile=percentile(TotalTime, 90) by bin(TimeGenerated, 15m)
| render timechart
Arka uç gecikme süresi
Arka uç GÇ'de harcanan sürenin istatistikleri (milisaniye olarak).
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(BackendTime), Median=percentile(BackendTime, 50), 90th_Percentile=percentile(BackendTime, 90) by bin(TimeGenerated, 15m)
| render timechart
İstemci gecikme süresi
İstemci GÇ'de harcanan sürenin (milisaniye) istatistikleri.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Average=avg(ClientTime), Median=percentile(ClientTime, 50), 90th_Percentile=percentile(ClientTime, 90) by bin(TimeGenerated, 15m)
| render timechart
Önbellek isabet oranı
Önbellek isabet/isabet oranı istatistikleri.
// To create an alert for this query, click '+ New alert rule'
ApiManagementGatewayLogs
| where TimeGenerated > ago(1d)
| summarize Cache_Miss=countif(Cache == "miss"), Cache_Hit=countif(Cache == "hit") by bin(TimeGenerated, 15m)
| extend Ratio=Cache_Hit / (Cache_Hit + Cache_Miss)
| project-away Cache_Hit , Cache_Miss
| render timechart