AzureAttestationDiagnostics tablosu için sorgular

Makale
11/05/2024

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

Herhangi bir yetkilendirme hatası var mı?

Yetkilendirmenin başarısız olduğu Kanıtlama sağlayıcısı isteklerinin sayısı.

// To create an alert for this query, click '+ New alert rule'
AzureAttestationDiagnostics
| where toint(ResultSignature) == 403
| summarize count() by ResourceUri, ResultSignature, _ResourceId
// ResultSignature contains HTTP status code returned by the request, (e.g.  200, 300, 401, etc.)
// ResourceUri contains the URI of the request

Yavaş istekler var mı?

1 saniyeden uzun süren Kanıtlama sağlayıcısı isteklerinin listesi.

// To create an alert for this query, click '+ New alert rule'
let threshold=1000; // let operator defines a constant that can be further used in the query
AzureAttestationDiagnostics
| where DurationMs > threshold
| summarize count() by OperationName, _ResourceId

Bu Kanıtlama sağlayıcısı ne kadar etkin?

Kanıtlama sağlayıcısının zaman içindeki işlem başına birim isteği eğilimini gösteren çizgi grafik.

AzureAttestationDiagnostics
| where TimeGenerated > ago(1d)
| summarize count() by bin(TimeGenerated, 1h), OperationName // Aggregate by hour
| render timechart

Bu kanıtlama sağlayıcısını kim çağırıyor?

IP adresleri ve istek sayılarıyla AAD UPN ile tanımlanan arayanların listesi.

AzureAttestationDiagnostics
| summarize count() by CallerIpAddress, tostring(Identity.callerAadUPN)

Kanıtlama ilkesinde herhangi bir değişiklik yapıldı mı?

Kanıtlama ilkesini veya ilke imzalama sertifikalarını değiştirmek için başarılı Kanıtlama sağlayıcısı isteklerinin listesi.

// To create an alert for this query, click '+ New alert rule'
let policyOperations = pack_array(
    "AddPolicyCertificate",
    "AddPolicyManagementCertificate",
    "AddPolicyManagementCertificates",
    "RemovePolicyCertificate",
    "RemovePolicyManagementCertificate",
    "RemovePolicyManagementCertificates",
    "ResetAttestationPolicy",
    "SetCurrentPolicy",
    "SetCurrentPolicyWithHttpMessagesAsync",
    "SetEffectiveAttestationPolicy",
    "DeleteCurrentPolicy",
    "DeletePolicy"
);
AzureAttestationDiagnostics
| where toint(ResultSignature) == 200
| where policyOperations contains OperationName
| take 100

Kanıtlama ilkesini yapılandırmaya çalışırken herhangi bir hata oluştu mu?

Kanıtlama ilkesini veya ilke imzalama sertifikalarını yapılandırmaya çalışan hataların listesi.

// To create an alert for this query, click '+ New alert rule'
let policyOperations = pack_array(
    "AddPolicyCertificate",
    "AddPolicyManagementCertificate",
    "AddPolicyManagementCertificates",
    "PrepareToSetPolicy",
    "PrepareToUpdatePolicy",
    "RemovePolicyCertificate",
    "RemovePolicyManagementCertificate",
    "RemovePolicyManagementCertificates",
    "ResetAttestationPolicy",
    "SetCurrentPolicy",
    "SetCurrentPolicyWithHttpMessagesAsync",
    "SetEffectiveAttestationPolicy",
    "DeleteCurrentPolicy",
    "DeletePolicy"
);
AzureAttestationDiagnostics
| where toint(ResultSignature) >= 300
| where policyOperations contains OperationName
| take 100

Aracılığıyla paylaş