WVDConnectionNetworkData tablosu için sorgular

  • Makale

Azure portalında bu sorguları kullanma hakkında bilgi için bkz . Log Analytics öğreticisi. REST API için bkz . Sorgu.

Zaman içinde ortalama gidiş dönüş süresi

10., 50. ve 90. yüzdebirlik dilimlerde 10 dk aralıklarla tüm bağlantılar arasında gidiş dönüş süresinin (Milisaniye cinsinden) grafiğini görüntüleyin.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Tüm bağlantılarda ortalama BW

10., 50. ve 90. yüzdebirlik dilimlerde 10 dk aralıklarla tüm bağlantılarda bant genişliği grafiğini (saniyede Kilobayt cinsinden) görüntüler.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

En yüksek gidiş dönüş süresine sahip ilk 10 kullanıcı

En yüksek ortalama gidiş dönüş süresine sahip ilk 10 kullanıcının listesini döndürür (Milisaniye cinsinden).

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

En düşük bant genişliğine sahip ilk 10 kullanıcı

En düşük ortalama bant genişliğine sahip ilk 10 kullanıcının listesini döndürür (saniye başına Kilobayt cinsinden).

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Gidiş dönüş süresi ve bant genişliği özeti

Her bağlantı için gidiş dönüş süresi (Milisaniye cinsinden) ve bant genişliği (Kilobayt cinsinden) için 90. yüzdebirlik dilimleri ve ek bağlantı ayrıntılarını döndürür.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion