make-series-Operator

Gilt für: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Erstellt eine Reihe angegebener aggregierter Werte entlang einer angegebenen Achse.

Syntax

T | make-series [MakeSeriesParameters] [Column =] Aggregation [default = DefaultValue] [, ...] on AxisColumn [from start] [to end] step step [by [Column =] GroupExpression [, ...]]

Erfahren Sie mehr über Syntaxkonventionen.

Parameter

Unterstützte make-series-Parameter

Alternativer Syntax

T | make-series [Column =] Aggregation [default = DefaultValue] [, ...] on AxisColumn in range(start, stop, step) [by [Column =] GroupExpression [, ...]]

Die generierten Reihen aus der alternativen Syntax unterscheiden sich von der Hauptsyntax in zwei Aspekten:

• Der stop-Wert ist inklusiv.
• Die Quantisierung der Indexachse wird mit bin() und nicht mit bin_at() generiert, was bedeutet, dass start in der generierten Reihe möglicherweise nicht enthalten ist.

Es wird empfohlen, die Hauptsyntax von make-series zu verwenden, nicht die alternative Syntax.

Gibt zurück

Die Eingabezeilen werden in Gruppen angeordnet, die dieselben Werte wie die by -Ausdrücke und der bin_at(AxisColumn,step,start)-Ausdruck aufweisen. Anschließend werden die angegebenen Aggregationsfunktionen über jede Gruppe berechnet, dabei wird eine Zeile für jede Gruppe erzeugt. Das Ergebnis enthält die by -Spalten, die Spalte AxisColumn und auch mindestens eine Spalte für jedes berechnete Aggregat. (Aggregationen über mehrere Spalten oder mit nicht numerischen Ergebnissen werden nicht unterstützt.)

Dieses Zwischenergebnis weist so viele Zeilen auf, wie es unterschiedliche Kombinationen aus by und bin_at(AxisColumn,step,start)-Werten gibt.

Schließlich werden die Zeilen aus dem Zwischenergebnis in Gruppen angeordnet, die dieselben Werte wie die by-Ausdrücke aufweisen, und alle aggregierten Werte werden in Arrays (Werte vom dynamic-Typ) angeordnet. Für jede Aggregation gibt es eine Spalte, die das zugehörige Array mit dem entsprechenden Namen enthält. Die letzte Spalte ist ein Array, das die Werte von AxisColumn enthält, die gemäß dem angegebenen Schritt klassifiziert sind.

Liste der Aggregationsfunktionen

Liste der Analysefunktionen für Zeitreihen

Eine vollständige Liste der Analysefunktionen für Reihen finden Sie unter Funktionen für die Zeitreihenverarbeitung.

Liste der Reiheninterpolationsfunktionen

• Hinweis: Interpolationsfunktionen nehmen standardmäßig null als fehlenden Wert an. Geben Sie daher default=double(null) in make-series an, wenn Sie beabsichtigen, Interpolationsfunktionen für die Reihe zu verwenden.

Beispiele

Eine Tabelle, die Arrays der Zahlen und Durchschnittspreise der einzelnen Früchte von jedem Lieferanten anzeigt, geordnet nach dem Zeitstempel mit dem angegebenen Bereich. Es gibt eine Zeile in der Ausgabe für jede einzelne Kombination von Obst und Lieferant. In den Ausgabespalten werden die Früchte, der Lieferant und die folgenden Arrays angezeigt: count, average und die gesamte Timeline (von 2016-01-01 bis 2016-01-10). Alle Arrays werden nach dem entsprechenden Zeitstempel sortiert, und alle Lücken werden mit Standardwerten aufgefüllt (in diesem Beispiel 0). Alle anderen Eingabespalten werden ignoriert.

T | make-series PriceAvg=avg(Price) default=0
on Purchase from datetime(2016-09-10) to datetime(2016-09-13) step 1d by Supplier, Fruit

let data=datatable(timestamp:datetime, metric: real)
[
  datetime(2016-12-31T06:00), 50,
  datetime(2017-01-01), 4,
  datetime(2017-01-02), 3,
  datetime(2017-01-03), 4,
  datetime(2017-01-03T03:00), 6,
  datetime(2017-01-05), 8,
  datetime(2017-01-05T13:40), 13,
  datetime(2017-01-06), 4,
  datetime(2017-01-07), 3,
  datetime(2017-01-08), 8,
  datetime(2017-01-08T21:00), 8,
  datetime(2017-01-09), 2,
  datetime(2017-01-09T12:00), 11,
  datetime(2017-01-10T05:00), 5,
];
let interval = 1d;
let stime = datetime(2017-01-01);
let etime = datetime(2017-01-10);
data
| make-series avg(metric) on timestamp from stime to etime step interval 

Wenn die Eingabe für make-series leer ist, erzeugt das Standardverhalten von make-series ein leeres Ergebnis.

let data=datatable(timestamp:datetime, metric: real)
[
  datetime(2016-12-31T06:00), 50,
  datetime(2017-01-01), 4,
  datetime(2017-01-02), 3,
  datetime(2017-01-03), 4,
  datetime(2017-01-03T03:00), 6,
  datetime(2017-01-05), 8,
  datetime(2017-01-05T13:40), 13,
  datetime(2017-01-06), 4,
  datetime(2017-01-07), 3,
  datetime(2017-01-08), 8,
  datetime(2017-01-08T21:00), 8,
  datetime(2017-01-09), 2,
  datetime(2017-01-09T12:00), 11,
  datetime(2017-01-10T05:00), 5,
];
let interval = 1d;
let stime = datetime(2017-01-01);
let etime = datetime(2017-01-10);
data
| take 0
| make-series avg(metric) default=1.0 on timestamp from stime to etime step interval 
| count 

Ausgabe

Die Verwendung von kind=nonempty in make-series führt zu einem nicht leeren Ergebnis der Standardwerte:

let data=datatable(timestamp:datetime, metric: real)
[
  datetime(2016-12-31T06:00), 50,
  datetime(2017-01-01), 4,
  datetime(2017-01-02), 3,
  datetime(2017-01-03), 4,
  datetime(2017-01-03T03:00), 6,
  datetime(2017-01-05), 8,
  datetime(2017-01-05T13:40), 13,
  datetime(2017-01-06), 4,
  datetime(2017-01-07), 3,
  datetime(2017-01-08), 8,
  datetime(2017-01-08T21:00), 8,
  datetime(2017-01-09), 2,
  datetime(2017-01-09T12:00), 11,
  datetime(2017-01-10T05:00), 5,
];
let interval = 1d;
let stime = datetime(2017-01-01);
let etime = datetime(2017-01-10);
data
| take 0
| make-series kind=nonempty avg(metric) default=1.0 on timestamp from stime to etime step interval 

Ausgabe