Metodo Session.Create

Crea una nuova istanza di una risorsa e restituisce il riferimento all'endpoint (EPR) del nuovo oggetto.

Sintassi

Session.Create( _
  ByVal resourceUri, _
  ByVal resource, _
  [ ByVal flags ] _
)

Parametri

resourceUri [in]

Identificatore della risorsa da creare.

Questo parametro può contenere uno dei seguenti elementi:

• URI con uno o più selettore. Tenere presente che il plug-in WMI non supporta la creazione di alcuna risorsa diversa da un listener del protocollo WS-Management .
• Oggetto ResourceLocator che può contenere selettori, frammenti o opzioni.
• Riferimento all'endpoint di indirizzamento WS, come descritto nello standard del protocollo WS-Management. Per altre informazioni sulla specifica pubblica per il protocollo di WS-Management, vedere Pagina Relativa alle specifiche di gestione.

resource

XML contenente il contenuto della risorsa.

flag [in, facoltativo]

Riservato. Deve essere 0.

Valore restituito

Richiesta di reimpostazione della nuova risorsa.

Commenti

Session.Create viene usato solo per la creazione di nuove istanze di una risorsa. Usare il metodo Session.Put per aggiornare le istanze esistenti di una risorsa. Dopo aver ottenuto il nuovo URI della risorsa, è possibile chiamare Session.Get per recuperare il nuovo oggetto. Il nuovo oggetto contiene le proprietà assegnate dal provider di risorse durante la creazione del nuovo oggetto. Ad esempio, se si crea un nuovo listener del protocollo WS-Management e si recupera l'oggetto listener usando Session.Get, si ottengono anche le proprietà Port, Enabled e ListenOn .

Tenere presente che il plug-in WMI non supporta la creazione di alcuna risorsa diversa da un listener del protocollo WS-Management.

La sintassi seguente viene usata per chiamare questo metodo.

uri = session.Create("<resourceUri>", "<resource>")

Esempio

Nell'esempio di codice VBScript seguente viene chiamato Session.Create per creare un listener nel computer locale.

'Create a WSMan object
Set oWsman = CreateObject( "WSMAN.Automation" )

'Create a Session object
Set oSession = oWsman.CreateSession

'Define resourceUri and inputXml 
resourceUri = "http://schemas.microsoft.com/wbem/wsman/1/"_
    & "config/Listener?Address=*+Transport=HTTP"

inputXml = _
    "<cfg:Listener xmlns:cfg=""https://schemas.dmtf.org/wbem/wsman/1/"_
    & "config/Listener.xsd"">" _
    & "<cfg:Hostname>" & GetFQDNName() & "</cfg:Hostname>" _            
    & "</cfg:Listener>"

'Perform the create operation.
response = oSession.Create( resourceUri, inputXml )
WScript.Echo "Response message: " & Chr(10) & response

Function GetFQDNName()
    Dim oShell, userDNSDomain, localComputerName
    Set oShell = CreateObject("WScript.Shell")
    userDNSDomain = oShell.ExpandEnvironmentStrings("%USERDNSDOMAIN%")

    localComputerName = _
        oShell.ExpandEnvironmentStrings("%ComputerName%")
    If userDNSDomain = "%USERDNSDOMAIN%" Then
        GetFQDNName= localComputerName
    Else
        GetFQDNName= localComputerName & "." & userDNSDomain
    End If
End Function

Requisiti

Vedi anche

sessione

Protocollo WS-Management